Le cache est une fonctionnalité intégrée dans tous les navigateurs Internet. Cela permet (en gros) d'éviter de recharger complètement une page si celle-ci n'a pas changé depuis la dernière fois qu'elle a été visitée.

En AS2, la gestion du cache était fastidieuse... Si une image devait être rechargée pour l'une ou l'autre raison, il fallait relancer un loadMovie. Il était également possible de charger la chose en cache en passant par la classe LoadVars, l'avantage étant qu'il n'est pas nécessaire de créer un clip vide temporaire :

var url:String = "myPicture.jpg";
var me:MovieClip = this;
var cache:LoadVars = new LoadVars();
cache.onLoad = function(Void):Void
{
   //chargement "réel" de l'image
   for (var i:Number=0 ; i<10 ; i++)
   {
       var container:MovieClip = me.createEmptyMovieClip("picture"+i, i);
       container.loadMovie(url);
       //positionnement...
   }
}
cache.load(url);

Ceci dit, il n'est jamais certain que l'image en question soit chargée dans tous les clips (le navigateur doit envoyer une requête pour chacune des images afin de s'assurer qu'elle n'a pas changé).

En AS3, la méthodologie reste la même mais par contre, une fois l'image chargée, celle-ci est réutilisable à volonté sans avoir à relancer un quelconque chargement dépendant de l'implémentation du navigateur ! Et cela se fait très simplement en combinant URLLoader et Loader (au même titre que MovieClip et LoadVars en AS2) :

var url:String = "myPicture.jpg";
var cache:URLLoader = new URLLoader();
cache.dataFormat = URLLoaderDataFormat.BINARY;
cache.addEventListener(Event.COMPLETE, onLoadComplete);
cache.load(new URLRequest(url));
 
function onLoadComplete(evt:Event):void
{
    //récupération des données binaires
    var db:ByteArray = cache.data;
 
    for (var i:int=0 ; i<10 ; i++)
    {
        var ldr:Loader = new Loader();
        ldr.loadBytes(db); //Contexte indépendant
        addChild(ldr);
        //positionnement...
    }
}

Vous noterez la puissance de la méthode loadBytes de la classe Loader qui permet de charger une image du cache (tout comme un SWF) sans même que le navigateur ne le sache ! La seule chose manquante est une méthode similaire pour la classe Sound... Je ne sais pas pourquoi Adobe a décidé de ne pas implémenter cette méthode. Une idée ? :)